FantasticLogo

1 collaborator

OVERVIEW

FantasticLogo is a NetLogo model for simulating the complex predator-prey dynamics of bleurghs and oopalamcas, two species native to planet Magy's northern hemisphere. It provides a platform for xenobiology research, allowing users to explore how alien species interact, compete, and adapt within an unfamiliar ecosystem.

Click here to play with this model online on NetLogo Web!

HOW IT WORKS

The model operates on a grid of patches, each representing a patch of soil where bleurghs grow and oopalamcas roam.

Oopalamcas are small, purple creatures with voracious appetites and a distinctive croak. Bleurghs are large, carnivorous plants that move slowly and capture prey with their funnel-shaped mouths. In the model, oopalamcas are the prey and bleurghs are the predators.

As the simulation runs, bleurghs grow on patches and, upon reaching maturity, can reproduce by dispersing seeds to random locations. Bleurghs prey on oopalamcas, regulating their population.

An oopalamca (prey) and a plasticoco (a harmless plant).

Oopalamca Plasticoco

An infant and an adult bleurgh (predator).

Oopalamca Bleurgh

HOW TO USE IT

Use the sliders on the left to adjust the initial populations and reproduction rates for bleurghs and oopalamcas, as well as other key parameters. When ready, click Setup to initialize the simulation, then click Go to begin observing the dynamics.

INTERFACE CONTROLS

CHOOSERS, INPUT BOXES, SLIDERS, AND SWITCHES

oopalamca-n: Slider for setting the initial number of oopalamcas (default: 50).
bleurgh-n: Slider for setting the initial number of bleurghs (default: 50).
oopalamca-reproduce: Slider for setting the probability (in percentage) of oopalamcas reproducing each tick (default: 15%).
bleurgh-gain-from-food: Slider for setting the energy bleurghs gain from consuming an oopalamca (default: 50).
bleurgh-reproduce: Slider for setting the probability (in percentage) of bleurghs reproducing each tick (default: 30%).

BUTTONS

Setup: Initializes the simulation with the selected parameters.
Go: Starts or resumes the simulation.

MONITORS AND PLOTS

Populations: Plot displaying the populations of oopalamcas and bleurghs over time.
Oopalamcas: Monitor showing the current number of oopalamcas.
Bleurghs: Monitor showing the current number of bleurghs.

THINGS TO NOTICE

Observe the cyclical nature of predator-prey relationships, where increases in the prey population lead to increases in the predator population, followed by declines in both populations.
Examine how varying reproduction rates and energy gains affect the stability and fluctuations of both species.
Analyze the conditions under which either species may face extinction or overpopulation.

THINGS TO TRY

Explore the impact of initial population sizes on long-term stability.
Experiment with different reproduction rates and energy gains to observe their effects on population dynamics.
Investigate the conditions leading to extinction or overpopulation of either species.

JOKES ASIDE...

FantasticLogo takes inspiration from René Laloux's 1973 masterpiece, La Planète Sauvage. The model's visual and conceptual design mirrors the film's hypnotic atmosphere, where the towering, blue-skinned Draags dominate a world teeming with surreal, alien flora and fauna. In this world, humans (known as Oms) are treated as mere pets, struggling to survive in an environment that is both beautiful and perilous.

The model's dynamics are grounded in the classic Lotka-Volterra equations, originally formulated by Alfred J. Lotka (1925) and Vito Volterra (1926), to describe predator-prey interactions. The code builds on Wilensky's (1997) Wolf Sheep Predation model.

(

HOW TO CITE

If you use this model, please cite it to acknowledge the effort invested in its development and maintenance.

To cite FantasticLogo please use the following format:

Vartanian, D. FantasticLogo: Predator-prey dynamics on planet Magy [Computer software]. https://doi.org/10.5281/zenodo.18122347

A BibLaTeX entry for LaTeX users is:

@software{vartanian,
  title = {FantasticLogo: Predator-prey dynamics on planet Magy},
  author = {Daniel Vartanian},
  doi = {https://doi.org/10.5281/zenodo.18122347},
  note = {Computer software}
}

HOW TO CONTRIBUTE

Contributions are welcome! Whether you want to report bugs, suggest features, or improve the code or documentation, your input is highly valued. Please check the code repository issues tab for existing issues or to open a new one.

LICENSE

Copyright (C) 2025 Daniel Vartanian

FantasticLogo is free software: you can redistribute it and/or modify it under
the terms of the GNU General Public License as published by the Free Software
Foundation, either version 3 of the License, or (at your option) any later
version.

This program is distributed in the hope that it will be useful, but WITHOUT ANY
WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR A
PARTICULAR PURPOSE. See the GNU General Public License for more details.

You should have received a copy of the GNU General Public License along with
this program. If not, see <https://www.gnu.org/licenses/>.

REFERENCES

Lotka, A. J. (1925). Elements of physical biology. Williams & Wilkins Company. http://archive.org/details/elementsofphysic017171mbp

Volterra, V. (1926). Fluctuations in the abundance of a species considered mathematically. Nature, 118(2972), 558-560. https://doi.org/10.1038/118558a0

Wilensky, U. (1997). NetLogo wolf sheep predation model [Computer software]. Center for Connected Learning and Computer Based Modeling at Northwestern University. http://ccl.northwestern.edu/netlogo/models/WolfSheepPredation

Comments and Questions

Daniel Vartanian

Full Model

Access the full model and documentation at: https://github.com/danielvartan/fantasticlogo

Posted about 11 hours ago

Click to Run Model

; FantasticLogo: Predator-Prey Dynamics on Planet Magy
;
; Version: 1.0.2
; Author: Daniel Vartanian
; Maintainer: Daniel Vartanian 
; License: GPLv3 
; Repository: 
;
; Require: NetLogo >= 7.0.3

globals [max-oopalamca]

breed [bleurghs bleurgh]
breed [oopalamcas oopalamca]
breed [plasticocos plasticoco]

bleurghs-own [energy]
oopalamcas-own [energy]

to setup
  clear-all

  set max-oopalamca 10000

  ask patches [
    let #color (sky + 4)

    set pcolor one-of (list
      (#color + (random-float 0.9))
      white
    )
  ]

  create-plasticocos 30 [
    set shape  "plasticoco"
    set size 2
    setxy random-xcor random-ycor
  ]

  create-oopalamcas oopalamca-n [
    set shape  "oopalamca"
    set size 2
    setxy random-xcor random-ycor

    set energy random random-between
      (0.25 * bleurgh-gain-from-food)
      (1.25 * bleurgh-gain-from-food)

    while [any? other turtles-here] [
      setxy random-xcor random-ycor
    ]
  ]

  create-bleurghs bleurgh-n [
    set shape "bleurgh"
    set size 3
    setxy random-xcor random-ycor

    set energy random-between
      (0.25 * bleurgh-gain-from-food)
      (1.25 * bleurgh-gain-from-food)

    while [any? other turtles-here] [
      setxy random-xcor random-ycor
    ]
  ]

  reset-ticks
end 

to go
  if ((not any? oopalamcas) and (not any? bleurghs)) [
    stop
  ]

  if (count oopalamcas > max-oopalamca) [
    user-message "The oopalamca have inherited the planet!"

    stop
  ]

  ask oopalamcas [
    move

    ifelse (random 100 < 50) [
      set energy energy - 1
    ] [
      set energy energy + 1
    ]

    if (energy < 0) [die]

    reproduce-oopalamcas
  ]

  ask bleurghs [
    eat-oopalamca
    set energy energy - 1

    if (energy < 0) [die]

    if (energy > (5 * bleurgh-gain-from-food)) [
      reproduce-bleurghs
    ]
  ]

  tick
end 

to move
  rt random 50
  lt random 50
  fd 1
end 

to reproduce-oopalamcas
  if (random-float 100 < oopalamca-reproduce) [
    set energy (energy / 2)

    hatch 1 [
      right random-float 360
      forward 1
    ]
  ]
end 

to eat-oopalamca
  let prey one-of oopalamcas-here ; (oopalamcas in-radius 1)

  if prey != nobody  [
    ask prey [die]
    set energy energy + bleurgh-gain-from-food
  ]
end 

to reproduce-bleurghs
  if (random-float 100 < bleurgh-reproduce) [
    set energy (energy / 2)

    hatch 1 [
      set energy 1
      setxy random-xcor random-ycor

      while [any? other turtles-here] [
        setxy random-xcor random-ycor
      ]
    ]
  ]
end 

to-report random-between [#x #y]
  report (random (#y - #x) + #x)
end

There are 5 versions of this model.

Uploaded by	When	Description	Download
Daniel Vartanian	about 9 hours ago	v1.0.2.1	Download this version
Daniel Vartanian	about 9 hours ago	v1.0.2	Download this version
Daniel Vartanian	about 9 hours ago	v1.0.1	Download this version
Daniel Vartanian	about 12 hours ago	v1.0.0	Download this version
Daniel Vartanian	about 12 hours ago	Initial upload	Download this version

Attached files

File	Type	Description	Last updated
FantasticLogo.png	preview	Logo	about 7 hours ago, by Daniel Vartanian	Download

This model does not have any ancestors.

This model does not have any descendants.

NetLogo